Creating wrapper task types

@CompileStatic
@CacheableTask
class PnpmWrapperTask extends AbstractJseWrapperTask {
    PnpmWrapperTask() {
        super('/gradle-jsecosystem-wrappers/pnpm', PnpmUtils.TOOL_NAME) (1)
    }

    @Override
    protected Map<String, String> getShellWrapperMap() { (2)
        SHELL_WRAPPER
    }

    @Override
    protected Map<String, String> getBatWrapperMap() { (3)
        BAT_WRAPPER
    }

    @Override
    protected Map<String, String> getPs1WrapperMap() { (4)
        PS1_WRAPPER
    }

    private static final Map<String, String> SHELL_WRAPPER = ['pnpm-wrapper-template.sh': 'pnpmw'].asImmutable()
    private static final Map<String, String> BAT_WRAPPER = ['pnpm-wrapper-template.bat': 'pnpmw.bat'].asImmutable()
    private static final Map<String, String> PS1_WRAPPER = ['pnpm-wrapper-template.ps1': 'pnpmw.ps1'].asImmutable()
}

@CompileStatic
class PnpmCacheBinariesTask extends AbstractJseCacheBinariesTask {

    PnpmCacheBinariesTask() {
        super('pnpm')
        this.binaryLocation = project.objects.property(String)
        this.binaryVersion = project.objects.property(String)
        this.envProperties = project.objects.mapProperty(String, String)
    }

    /**
     * Sets the toolchain for the lifecycle command task.
     *
     * @param tc Toolchain provider
     */
    void setToolchain(Provider<? extends JsePnpmToolchain> tc) { (1)
        this.binaryLocation.set(tc.flatMap { it.executable.map { f -> f.absolutePath } })
        this.binaryVersion.set(tc.flatMap { it.executableVersion })

        final env = tc.flatMap { t -> (2)
            PnpmUtils.minimalPnpmNodeEnv(t, providerTools())
        }.map { m ->
            final loc = m['PNPM_HOME']
            [
                PNPM_HOME    : loc,
                NODE_BIN_PATH: loc
            ]
        }

        this.envProperties.set(env)
    }

    /**
     * Obtains location of executable binary or script
     *
     * @return Location of executable as a string
     */
    @Override
    protected Provider<String> getBinaryLocationProvider() {
        this.binaryVersion
    }

    /**
     * Obtains version of binary or script
     *
     * @return Version as a string. Can be {@code null}.
     */
    @Override
    protected Provider<String> getBinaryVersionProvider() {
        this.binaryLocation
    }

    /**
     * Obtains a description to be added to the cached binary properties file.
     *
     * @return Description. Never {@code null}.
     */
    @Override
    protected String getPropertiesDescription() {
        'Properties for executing pnpm'
    }

    @Override
    protected Map<String, String> getAdditionalProperties() {
        super.additionalProperties + envProperties.get()
    }

    private final Property<String> binaryLocation
    private final Property<String> binaryVersion
    private final MapProperty<String, String> envProperties
}